Cloud Home Automation Series Part 4 : Connected Light Bulb using AWS, ESP32 & Arduino

[Updated - 1st March, 2020] : Course updated, now you can control your connected light either using Google Assistant or Alexa. Kindly check out the Bonus section at the end of the course.

Welcome to

SIMPLE LEARNING

In the fourth part, we will create an automated system to make the home light bulb connected to the web using AWS, an ESP32 board, a relay module and Arduino Code.

scratch and make cost-effective solutions

The following series split into four parts (refer below) with very simple and clear instructions to provision a home automation system to control house appliances through the web.

• Part I - Connect your device (ESP32) to AWS cloud.
• Part II - Use Device Shadow Service (AWS IoT) to control ESP32 inbuilt led using MQTT client.
• Part III - Create a secure web client hosted in Node-RED to control ESP32 inbuilt led.
• Part IV - The Real Deal: Create an automated system to make the light bulb connected to the web using AWS, an ESP32 board and a relay module.

Prerequisites:

1. It's the continuation of the following series. Make sure you have exercised Part I - Connect your device (ESP32) to AWS cloud rigorously.
2. This tutorial mostly covers hands-on, prior knowledge of AWS IoT is an advantage. to check AWS Official IoT Documentation.
3. A 2 channel relay module (Easily available in / or Local Robotics Shop) and a power bank to power up the ESP32.

Learning Objectives:

1. By using a web client, we will turn ON/OFF the light bulb by using AWS, an ESP32 board, a relay module and Arduino Code. We will leverage the power of Device Shadow which is very effective in case of power loss and connectivity issue. The device shadow stores the desired state and when the light bulb establishes the connection, the desired state gets synced.

2. Bonus - Toggle the light by using Google Assistant or Alexa. 

So let's see something happen now.

/*********
  Gourav Das
  Complete project details at //gzht888.com/cloud-home-automation-series-part-4-connected-light-bulb-using-aws-esp32-and-arduino-94n377d
  The above copyright notice and this permission notice shall be included in all
  copies or substantial portions of the Software.
*********/

#include <AWS_IOT.h>
#include <WiFi.h>
#include <ArduinoJson.h>

AWS_IOT lightbulb;
int relay_pin = 13; // Relay Pin

char WIFI_SSID[]="Wifi-Name";
char WIFI_PASSWORD[]="Wifi_Password";
char HOST_ADDRESS[]="************-***.iot.us-east-1.amazonaws.com";  //AWS IoT Custom Endpoint Address
char CLIENT_ID[]= "ESP32";
char SHADOW_GET[]= "$aws/things/{Thingname}/shadow/get/accepted";
char SENT_GET[]= "$aws/things/{ThingName}/shadow/get";
char SHADOW_UPDATE[]= "$aws/things/{ThingName}/shadow/update";

int status = WL_IDLE_STATUS;
int msgReceived=0;
char payload[512];
char reportpayload[512];
char rcvdPayload[512];

void mySubCallBackHandler (char *topicName, int payloadLen, char *payLoad)
{
    strncpy(rcvdPayload,payLoad,payloadLen);
    rcvdPayload[payloadLen] = 0;
    msgReceived = 1;
}

void updateShadow (int power)
{ 
  sprintf(reportpayload,"{\"state\": {\"reported\": {\"power\": \"%d\"}}}",power);
  delay(3000);   
    if(lightbulb.publish(SHADOW_UPDATE,reportpayload) == 0)
      {       
        Serial.print("Publish Message:");
        Serial.println(reportpayload);
      }
    else
      {
        Serial.println("Publish failed");
        Serial.println(reportpayload);   
      }  
} 

void setup() {
  Serial.begin(115200);
  pinMode(relay_pin, OUTPUT);
  delay(2000);  

    while (status != WL_CONNECTED)
    {
        Serial.print("Attempting to connect to SSID: ");
        Serial.println(WIFI_SSID);
        // Connect to WPA/WPA2 network. Change this line if using open or WEP network:
        status = WiFi.begin(WIFI_SSID, WIFI_PASSWORD);

        // wait 5 seconds for connection:
        delay(5000);
    }

    Serial.println("Connected to wifi");

    if(lightbulb.connect(HOST_ADDRESS,CLIENT_ID)== 0) //Connect to AWS IoT COre
    {
        Serial.println("Connected to AWS");
        delay(1000);

        if(0==lightbulb.subscribe(SHADOW_GET,mySubCallBackHandler)) //Subscribe to GET Shadow Service
        {
            Serial.println("Subscribe Successfull");
        }
        else
        {
            Serial.println("Subscribe Failed, Check the Thing Name and Certificates");
            while(1);
        }
    }
    else
    {
        Serial.println("AWS connection failed, Check the HOST Address");
        while(1);
    }
  
  //Sent Empty string to fetch Shadow desired state
  delay(3000);   
    if(lightbulb.publish(SENT_GET,"{}") == 0)
      {       
        Serial.print("Empty String Published\n");
      }
    else
      {
        Serial.println("Empty String Publish failed\n");
      }     
}

void loop() {
  
 if(msgReceived == 1)
    
  {
        msgReceived = 0;
        Serial.print("Received Message:");
        Serial.println(rcvdPayload);
        StaticJsonDocument<256> doc;
        deserializeJson(doc, rcvdPayload);
        
    // Test if parsing succeeds.
        if (doc.isNull()) {
        Serial.println("parseObject() failed");
        return;
        }
    
        int power = doc["state"]["desired"]["power"];
        Serial.println(power);
        if(power == 1)
        digitalWrite(relay_pin, LOW);
        else if(power == 0)
        digitalWrite(relay_pin, HIGH);
    updateShadow(power);  
    }  
}

We need to add a library in Arduino IDE, go to Tools → Manage Libraries. Search for ArduinoJson (by Benoit Blanchon), select the latest 6.x.x version only and click install. The code won't work on 5.x.x and below versions. Also, remember that we have used AWS_IOT library in the code to integrate ESP32 with AWS. If you are unaware, go to Part 1 of the series. Also, check the Certificates enrollment section under Hardware integration.

Code Modifications

char WIFI_SSID[]="Wifi-Name";
char WIFI_PASSWORD[]="Wifi_Password";
char HOST_ADDRESS[]="************-***.iot.us-east-1.amazonaws.com";  //AWS IoT Custom Endpoint Address
char CLIENT_ID[]= "ESP32";
char SHADOW_GET[]= "$aws/things/{Thingname}/shadow/get/accepted";
char SENT_GET[]= "$aws/things/{ThingName}/shadow/get";
char SHADOW_UPDATE[]= "$aws/things/{ThingName}/shadow/update";

Update the necessary details, skip

CLIENT_ID[]= "ESP32"

HOST_ADDRESS[]

{ThingName}

Thing Name

Manage

ESP32 Wiring

Warning:

In this exercise, we’re dealing with the mains voltage . Playing with mains voltage is like playing with fire. If you’re not familiar with mains voltage seek help. While programming the ESP or wiring your circuit make sure everything disconnected from the mains voltage.

At first, we will connect the jumper wires (F/F) with 2 channel relay module, as shown below. We will use an extension cord to light up the bulb, as a

precautionary measure

Note: Never touch the relay module when powered from the mains voltage.

• ESP32 VIN to Relay VCC
• ESP32 GND to Relay GND
• ESP32 D13 to Relay IN1
• Relay COM1 to Main Power Source
• Relay NO1 to Bulb

Once we have built the above connection we are almost done. Now, power on the ESP32 by using an external power source (Power Bank), wait for some time for the connection to establish and also we need to Switch ON the main power of the bulb for to make the circuitry functioning. Now we are going to test the web endpoints we have created in part 3, hit your Node-RED primary URL followed by /ON, AWS (e.g.

//52.90.186.136:1880/ON

1. Be gentle while turning ON/OFF the bulb, it may get stuck if clicked very fast. Reset will surely help in that case, press EN in ESP32 to re-establish the connection with AWS.
2. AWS Device shadow is a powerful tool. In case of power loss or connectivity issue, the device shadow stores the desired state which it receives from the web-client hosted in Node-RED. When the light bulb establishes the link, the desired state gets synced. You can try it out by taking the mains power supply of the bulb after that send the desired state (ON/OFF) request from the web-client. When you powered back the Bulb you will see the magic. 🧙‍♀️ 🧙‍♂️

Congratulations on completing the 4th part :)

Bonus

for step-by-step instructions. 

Kindly Share & Comment only if you find it useful and help me on my mission to educate and familiarize people in the world of digitization 💪 #This is a Free tutorial and all my upcoming tutorials will be free and accessible from Public forums.# Appreciate if you drop me a note on 

 & share your opinion. Don't worry, I don't bite 👻 so don't shy away 🏃🏻‍♀️ 🏃🏻. Your feedback will help me to come up  with more awesome contents on the internet.